Unlabeled with No Choice

[sisley]

Hello,

Thank you for providing this discussion forum. I have found it and the Ngene documentation very useful. I am trying to create what I think is a simple experimental design consisting of 4 attributes, 2 of which are dummies. When I use the following syntax:

Design
;alts = alt1*, alt2*, alt3
;rows = 12
;eff = (mnl,d)
;alg = mfederov
;model:
U(alt1) = b2[-0.1] * PRICE[0.89,1.19,1.49] + b3.dummy[0] * BOTTLE[0,1] +
b4.dummy[0] * PROD[0,1] + b5[-0.0001] * CF[50,500,1000] /
U(alt2) = b2 * PRICE + b3.dummy * BOTTLE + b4.dummy * PROD + b5 * CF
$

I get reasonable results. After a few minutes it finds a design with an S estimate of 186 and everything looks reasonable. However, if I remove 'alt3' from the list of alternatives, I get much worse results, with an S estimate greater than 1000 after a few minutes.

Why is the presence of alt3, the no-choice option with no utility function, so critical to the outcome?

Also, I am interested in running experiments without a no-choice alternative, so I tried running the following:

Design
;alts = alt1*, alt2*, alt3*
;rows = 12
;eff = (mnl,d)
;alg = mfederov
;model:
U(alt1) = b2[-0.1] * PRICE[0.89,1.19,1.49] + b3.dummy[0] * BOTTLE[0,1] +
b4.dummy[0] * PROD[0,1] + b5[-0.0001] * CF[50,500,1000] /
U(alt2) = b2 * PRICE + b3.dummy * BOTTLE + b4.dummy * PROD + b5 * CF /
U(alt3) = b2 * PRICE + b3.dummy * BOTTLE + b4.dummy * PROD + b5 * CF
$

This causes Ngene to crash every time. Any help on what's going on would be much appreciated!

-steve

[Michiel Bliemer]

(1) The reason is because alt1 and alt2 are very similar. Your priors are very small, so there are only minimal differences in utilities between alt1 and alt2. alt3 on the other hand is a clearly different alternative, thereby proving more information for taste preferences.

(2) Please use ;alg = mfederov(candidates = 1000).

[sisley]

Thank you very much for the reply! Adding candidates = 1000 does solve the Ngene crashing issue. I will try running an online pilot test to get some better estimates for my priors.

Thanks again.

-steve