Should I use equal or specific coefficients for the same attributes in a two-utility funcion experiment?

[tfeldens]

Dear community, I am a new user of NGene and I am working on my first design.
I have a labelled experiment with two alternatives plus an opt-out in which I have the same attributes for both. Although I have the same attributes, I do have different levels for them. I could run my design like this:

design

;alts = Visit*, Saliva*, opt-out
;rows = 11
;eff = (mnl,d)
;cond:
if(Visit.V_place = 1, Visit.price = [170,120]),
if(Visit.V_place = 2, Visit.price = [40,30])

;model:

U(Visit) = asc_Visit ?
+ b1 * specificity[95,98]
+ b2 * V_place[1,2] ?1=PrivateClinic, 2=PublicClinic
+ b3 * price[170,120,40,30] ?prices in euros

/

U(Saliva) =
+ b1 * S_specificity[98,99]
+ b2 * S_place[3,4] ?3=House, 4=Pharmacy
+ b3 * S_price[40,30,20] ?prices in euros


$

OR alternatively I could use my design like this:

design

;alts = Visit, Saliva, opt-out
;rows = 11
;eff = (mnl,d)
;cond:
if(Visit.V_place = 1, Visit.price = [170,120]),
if(Visit.V_place = 2, Visit.price = [40,30])

;model:

U(Visit) = asc_Visit ?
+ b1 * specificity[95,98]
+ b2 * V_place[1,2] ?1=PrivateClinic, 2=PublicClinic
+ b3 * price[170,120,40,30] ?prices in euros

/

U(Saliva) =
+ b4 * S_specificity[98,99]
+ b5 * S_place[3,4] ?3=House, 4=Pharmacy
+ b6 * S_price[40,30,20] ?prices in euros

$

where the only thing that has changed was that in the first design I am using the same b1, b2 and b3 coefficients while I am using b1, b2, b3, b4, b5 and b6 in the second.

I would like to be able to compare specificity and price between the two alternatives. My question is: which of the two designs should I use, and what are they implicitly implying?

Extra question: my opt out is not been showed. Is there anything I am missing?

Thank you so much,

[Michiel Bliemer]

For generic numerical attributes specificity and price you could choose between a generic or alternative-specific parameter, but for categorical variable place you MUST use an alternative-specific parameter because the levels are different and need to be dummy coded.

I would generally recommend choosing alternative-specific parameters for labelled alternatives. This allows you to estimate both alternative-specific parameters or generic parameters later during the model estimation phase. During model estimation, you can do a hypothesis test to see whether b1=b4 and whether b4=b6.

Note that you also need to add an alternative-specific constant for Saliva.

I would also recommend changing the number of rows to allow attribute level balance (so it needs to be divisible by 2 and 4 levels, which is not possible with 11 rows). And to increase the variation in the data (to allow estimation of interaction effects for example) consider increasing it to 24 and block it in two blocks.

Code: Select all

design
;alts = Visit, Saliva, opt-out
;rows = 24
;block = 2
;eff = (mnl,d)
;cond:
if(Visit.V_place = 1, Visit.price = [170,120]),
if(Visit.V_place = 2, Visit.price = [40,30])
;model:
U(Visit) = asc_Visit ?
+ b1 * specificity[95,98]
+ b2.dummy * V_place[1,2] ?1=PrivateClinic, 2=PublicClinic
+ b3 * price[170,120,40,30] ?prices in euros
/
U(Saliva) = asc_Saliva
+ b4 * S_specificity[98,99]
+ b5.dummy * S_place[3,4] ?3=House, 4=Pharmacy
+ b6 * S_price[40,30,20] ?prices in euros
$

Regarding the opt-out alternative, it is not shown in the Inspect screen (because there are no levels to show), but you simply manually add this third option in he survey instrument.

Michiel